Cara Membuat Aplikasi Penjualan V.1 Berbasis Excel Part 2

Posted by Admin

Cara Membuat Aplikasi Penjualan Berbasis Excel

Cara Membuat Aplikasi Penjualan V.1 Berbasis Excel Part 2 - Pada postingan kali ini saya akan melanjutkan tutorial tentang cara membuat aplikasi penjualan v.1 berbasis vba excel. Sahabat excel pada part 2 ini kita akan membuat sebuah form supplier dimana form supplier ini digunakan untuk menyimpan data dari supplier ketika kita melakukan transaksi pembelian barang.

Jika anda sudah mengikuti tutorial cara membuat aplikasi penjualan pada part 1 sebenarnya anda sudah bisa membuat coding sendiri pada form supplier ini, hanya saja anda harus mengeditnya sedikit.

Nah, Bagi anda yang belum memiliki filenya silahkan download pada postingan sebelumnya Cara Membuat Aplikasi Penjualan V.1 Part 1.

Kunjungi Juga: Aplikasi Inventory Purchase Sale Order System Gratis

Cara Membuat Aplikasi Penjualan Berbasis Excel

Baiklah sahabat excel tanpa berlama-lama silahkan ikuti saja langkah-langkah cara membuat form supplier aplikasi penjualan v.1 di bawah ini.

1. Buat Name Range

Sebelum kita membuat form supplier pada jendela visual basic, silahkan buat/beri nama rangenya terlebih dahulu.

Caranya, Klik Tab Formulas – Name Manager - New buatlah rumusnya seperti berikut:

Rumus Name Range Tabel Barang

Name: TBLSUPPLIER

Refers To: =OFFSET(Supplier!$A$2;0;0;COUNTA(Supplier!$A$2:$A$5000);5)

Rumus Name Range Kode Barang

Name : KODESUPPLIER

Refers To: =OFFSET(Supplier!$A$2;0;0;COUNTA(Supplier!$A$2:$A$5000);1)

Rumus Name Range Cari Barang

Name: CARIDATASUPPLIER

Refers To: =OFFSET(Supplier!$L$5;0;0;COUNTA(Supplier!$L$5:$L$5000);5)

2. Buat Form Supplier

Setelah selesai memberi nama range pada name manager, berikutnya kita akan membuat form supplier dan disainlah seperti berikut.

Cara Membuat Aplikasi Penjualan V.1 Berbasis Vba Excel PART 2

Form Supplier

Komponen yang digunakan:

NAMA KOMPONEN	JUMLAH
Frame	2
Label	8
TextBox	6
ComboBox	1
CommandButton	7
ListBox	1

Setelah anda selesai mendisain formnya, silahkan ganti Name Label, TextBox, ComboBox, CommandButton, dan Listbox pada properties sesuai keinginan anda.

Kunjungi Juga: Cara Membuat Form Settingan Printer di Vba Excel

3. Input Coding Form Supplier

Setelah selesai membuat form, langkah berikutnya kita akan melakukan penginputan coding dimana coding ini berfungsi untuk memproses data sesuai perintah yang kita inginkan nantinya.

Silahkan input coding perintah/prosedur bersih, aktif dan Nonaktif

Sub Bersih()
    Me.Kode.Value = ""
    Me.Nama.Value = ""
    Me.Alamat.Value = ""
    Me.Telpon.Value = ""
    Me.Email.Value = ""
End Sub

Sub NonAktif()
Me.Kode.Enabled = False
Me.Nama.Enabled = False
Me.Alamat.Enabled = False
Me.Telpon.Enabled = False
Me.Email.Enabled = False
End Sub

Sub Aktif()
Me.Nama.Enabled = True
Me.Alamat.Enabled = True
Me.Telpon.Enabled = True
Me.Email.Enabled = True
End Sub

4. Input Coding Menampilkan Data Barang Ke ListBox

Sub TampilDataSupplier()
Me.TABELSUPLIER.RowSource = "TBLSUPPLIER"
Me.TABELSUPLIER.ColumnHeads = True
Me.TABELSUPLIER.ColumnCount = 5
Me.TABELSUPLIER.ColumnWidths = 80 & "; " & 120 & "; " & 150 & "; " & 100 & "; " & 120 & ";"
End Sub
Private Sub UserForm_Initialize()
On Error Resume Next
'Menampilkan Judul Data Supplier
Call TampilDataSupplier
'Menampilkan Jumlah Data Pada Listbox
Me.JML.Caption = Me.TABELSUPLIER.ListCount
Me.KATAKUNCI.Enabled = False
With BERDASARKAN
    .AddItem "Kode Supplier"
    .AddItem "Nama Supplier"
End With
Call NonAktif
End Sub

5. Input Coding Tombol New

Private Sub BARU_Click()
    Call Aktif
    Me.Kode.Enabled = True
    Me.Kode.SetFocus
    Me.SIMPAN.Enabled = True
    Me.BATAL.Enabled = True
End Sub

6. Input Coding Simpan

Private Sub SIMPAN_Click()
Dim DataSuplier As Object
Set DataSuplier = Sheet8.Range("A50000").End(xlUp)
If Me.Kode.Value = "" _
    Or Me.Nama.Value = "" _
    Or Me.Alamat.Value = "" _
    Or Me.Telpon.Value = "" _
    Or Me.Email.Value = "" Then
    Call MsgBox("Data Supplier harus lengkap", vbInformation, "Data Supplier")
Else
    DataSuplier.Offset(1, 0).Value = Me.Kode.Value
    DataSuplier.Offset(1, 1).Value = Me.Nama.Value
    DataSuplier.Offset(1, 2).Value = Me.Alamat.Value
    DataSuplier.Offset(1, 3).Value = Me.Telpon.Value
    DataSuplier.Offset(1, 4).Value = Me.Email.Value
    Call MsgBox("Data Supplier Berhasil di Simpan", vbInformation, "Data Supplier")
    Me.TABELSUPLIER.RowSource = Sheet8.Range("TBLSUPPLIER").Address(EXTERNAL:=True)
    Me.JML.Caption = Me.TABELSUPLIER.ListCount
End If
    Call Bersih
    Call NonAktif
    Me.SIMPAN.Enabled = False
End Sub
7. Input Coding Update/Edit
Private Sub UPDATE_Click()
Dim UbahData As Object
If Me.Kode.Value = "" Then
    Call MsgBox("Pilih data pada tabel data terlebih dahulu", vbInformation, "Ubah Data")
Else
    Set UbahData = Sheet8.Range("A2:A50000").Find(What:=Me.Kode.Value, LookIn:=xlValues)
    UbahData.Offset(0, 0).Value = Me.Kode.Value
    UbahData.Offset(0, 1).Value = Me.Nama.Value
    UbahData.Offset(0, 2).Value = Me.Alamat.Value
    UbahData.Offset(0, 3).Value = Me.Telpon.Value
    UbahData.Offset(0, 4).Value = Me.Email.Value
    Call MsgBox("Data Berhasil diUpdate", vbInformation, "Update Data")
End If
    Call Bersih
    Call NonAktif
    Me.UPDATE.Enabled = False
    Me.DELETE.Enabled = False
    Me.BATAL.Enabled = False
End Sub

8. Input Coding Delete/Hapus

Private Sub DELETE_Click()
If Me.Kode.Value = "" Then
    Call MsgBox("Pilih data pada tabel data terlebih dahulu", vbInformation, "Hapus Data")
Else
Select Case MsgBox("Anda akan menghapus data" _
& vbCrLf & "Apakah anda yakin?" _
, vbYesNo Or vbQuestion Or vbDefaultButton1, "Hapus data")
Case vbNo
Exit Sub
Case vbYes
End Select
    Set HapusData = Sheet8.Range("A2:A50000").Find(What:=Me.Kode.Value, LookIn:=xlValues)
    HapusData.Offset(0, 0).Value = ""
    HapusData.Offset(0, 1).Value = ""
    HapusData.Offset(0, 2).Value = ""
    HapusData.Offset(0, 3).Value = ""
    HapusData.Offset(0, 4).Value = ""
    Call MsgBox("Data Supplier Berhasil di Hapus", vbInformation, "Hapus Data")
    Me.TABELSUPLIER.RowSource = Sheet8.Range("TBLSUPPLIER").Address(EXTERNAL:=True)
    Me.JML.Caption = Me.TABELSUPLIER.ListCount
End If
    Call Bersih
    Urut_Supplier
    Call NonAktif
    Me.UPDATE.Enabled = False
    Me.DELETE.Enabled = False
    Me.BATAL.Enabled = False
End Sub
9. Input coding Batal
Private Sub BATAL_Click()
Me.SIMPAN.Enabled = False
Me.UPDATE.Enabled = False
Me.DELETE.Enabled = False
Me.BATAL.Enabled = False
Call NonAktif
Call Bersih
End Sub

10. Input Coding Cetak

Private Sub CETAKSUPPLIER_Click()
If Me.TABELSUPLIER.RowSource = "" Then
    Call MsgBox("Tidak ada data yang dicetak", vbInformation, "Cetak Supplier")
Else
    Select Case MsgBox("DATA SUPPLIER Akan Di Cetak" _
        & vbCrLf & "Apakah anda yakin?" _
        , vbYesNo Or vbQuestion Or vbDefaultButton1, "Cetak Data Supplier")
        Case vbNo
        Exit Sub
        Case vbYes
    End Select
    Sheet8.PrintOut
End If
End Sub

11. Input Coding Close/Keluar

Private Sub KELUAR_Click()
Unload Me
End Sub

12. Input Coding ListBox

Private Sub TABELSUPLIER_DblClick(ByVal Cancel As MSForms.ReturnBoolean)
On Error GoTo SALAH
Me.Kode.Value = Me.TABELSUPLIER.Value
Me.Nama.Value = Me.TABELSUPLIER.Column(1)
Me.Alamat.Value = Me.TABELSUPLIER.Column(2)
Me.Telpon.Value = Me.TABELSUPLIER.Column(3)
Me.Email.Value = Me.TABELSUPLIER.Column(4)
Me.UPDATE.Enabled = True
Me.DELETE.Enabled = True
Me.BATAL.Enabled = True
Me.Kode.Enabled = False
Call Aktif
Exit Sub
SALAH:
Call MsgBox("Pilih Data pada tabel data", vbInformation, "Data Supplier")
End Sub

13. Input Coding Pencarian Data Supplier

Sebelum membuat coding pencarian data supplier silahkan anda tambahkan/buat rumus pada tab Data - Advanced - Advanced Filter buatlah rumusnya seperti gambar dibawah atau bisa anda kunjungi pada postingan sebelumnya disini cara membuat aplikasi penjualan part 1.

Kunjungi Juga: Aplikasi Toko Penjualan (APOS) Gratis Custom UI

Cara Membuat Aplikasi Penjualan Berbasis Excel Part 2

Settingan Advanced Filter

Private Sub KATAKUNCI_Change()
'Perintah Mengatasi data jika tidak ditemukan
On Error GoTo SALAH
Dim CARISUPPLIER As Object
'Perintah menentukan tempat pencarian data
Set CARISUPPLIER = Sheet8
'Perintah Menentukan tempat Kriteria Pencarian
CARISUPPLIER.Range("J1").Value = BERDASARKAN.Value
CARISUPPLIER.Range("J2").Value = Me.KATAKUNCI.Value
'Perintah Melakukan pencarian
CARISUPPLIER.Range("A1").CurrentRegion.AdvancedFilter Action:=xlFilterCopy, CriteriaRange:= _
Sheet8.Range("J1:J2"), CopyToRange:=Sheet8.Range("L4:P4"), Unique:=False
'Perintah Memunculkan hasil pencarian
Me.TABELSUPLIER.RowSource = Sheet8.Range("CARIDATASUPPLIER").Address(EXTERNAL:=True)
Me.JML.Caption = Me.TABELSUPLIER.ListCount
'Perintah lanjutan On Error
Exit Sub
SALAH:
Call MsgBox("Maaf Data Yang Anda Cari Tidak di Temukan", vbInformation, "Data Supplier")
End Sub

Sekian dulu tentang Cara Membuat Aplikasi Penjualan V.1 Part 2 Berbasis VBA Excel ini. Mohon maaf kalau ada kesalahan pada penulisan coding, karna saya baru belajar.

Kunjungi Juga: Cara Membuat Aplikasi Penjualan V.1 Berbasis Vba Excel Part 3

Jika ada pertanyaan, silahkan tinggalkan komentarnya pada kolom yang sudah tersedia di bawah. Berkomentarlah dengan sopan dan mari kita belajar bersama.

Terima kasih

Excel Tutorial Vba Excel